Формат Формат iCalendar

Наверх  Предыдущий  Следующий

iCalendar - это распостранённый формат обмена информацией о календаре и расписании в сети Интернет.

Примечание: Для получнеия более детальной информации, можете обратиться к стандарту RFC 2445.

 

 

Формат

 

"FREQ"=freq *(

 

              ; здесь можно указать ключевые слова UNTIL или COUNT,

              ; но UNTIL и COUNT не должны находиться в одной строке одновременно

 

              ( ";" "UNTIL" "=" enddate ) /

              ( ";" "COUNT" "=" 1*DIGIT ) /

 

              ; остальные ключевые слова необязательны,

              ; он они не должны встречаться более одного раза

 

              ( ";" "INTERVAL" "=" 1*DIGIT )          /

              ( ";" "BYSECOND" "=" byseclist )        /

              ( ";" "BYMINUTE" "=" byminlist )        /

              ( ";" "BYHOUR" "=" byhrlist )           /

              ( ";" "BYDAY" "=" bywdaylist )          /

              ( ";" "BYMONTHDAY" "=" bymodaylist )    /

              ( ";" "BYYEARDAY" "=" byyrdaylist )     /

              ( ";" "BYWEEKNO" "=" bywknolist )       /

              ( ";" "BYMONTH" "=" bymolist )          /

              ( ";" "BYSETPOS" "=" bysplist )         /

              ( ";" "WKST" "=" weekday )              /

              ( ";" x-name "=" text )

              )

 

freq       = "SECONDLY" / "MINUTELY" / "HOURLY" / "DAILY"

       / "WEEKLY" / "MONTHLY" / "YEARLY"

 

enddate    = date

enddate    =/ date-time

 

byseclist  = seconds / ( seconds *("," seconds) )

 

seconds    = 1DIGIT / 2DIGIT

 

byminlist  = minutes / ( minutes *("," minutes) )

 

minutes    = 1DIGIT / 2DIGIT

 

byhrlist   = hour / ( hour *("," hour) )

 

hour       = 1DIGIT / 2DIGIT

 

bywdaylist = weekdaynum / ( weekdaynum *("," weekdaynum) )

 

weekdaynum = [([plus] ordwk / minus ordwk)] weekday

 

plus       = "+"

 

minus      = "-"

 

ordwk      = 1DIGIT / 2DIGIT

 

weekday    = "SU" / "MO" / "TU" / "WE" / "TH" / "FR" / "SA"

 

bymodaylist = monthdaynum / ( monthdaynum *("," monthdaynum) )

 

monthdaynum = ([plus] ordmoday) / (minus ordmoday)

 

ordmoday   = 1DIGIT / 2DIGIT

 

byyrdaylist = yeardaynum / ( yeardaynum *("," yeardaynum) )

 

yeardaynum = ([plus] ordyrday) / (minus ordyrday)

 

ordyrday   = 1DIGIT / 2DIGIT / 3DIGIT

 

bywknolist = weeknum / ( weeknum *("," weeknum) )

 

weeknum    = ([plus] ordwk) / (minus ordwk)

 

bymolist   = monthnum / ( monthnum *("," monthnum) )

 

monthnum   = 1DIGIT / 2DIGIT

 

bysplist   = setposday / ( setposday *("," setposday) )

 

setposday  = yeardaynum

 

 

Примеры

 

Последний рабочий день месяца:

FREQ=MONTHLY;BYDAY=MO,TU,WE,TH,FR;BYSETPOS=-1

 

Десять встреч через день:

FREQ=DAILY;COUNT=10;INTERVAL=2

 

14 июля 1997 года, в 1:30 PM:

19970714T173000Z

 

 

Смотрите также:

Формат Cron

Планировщик