The following batch file first deletes an existing log file and then it installs all the Microsoft Self-Extractor files that are contained in the directory in which you have placed the batch file.

@echo off

del %temp%\oupdates.txt /q

for /f "delims=-; tokens=1,2,3,4,5" %%i in ('dir /b *kb*.exe') do echo %%j-%%i-%%k-%%l-%%m >> %temp%\oupdates.txt

for /f "delims=-; tokens=1,2,3,4,5" %%i in ('type %temp%\oupdates.txt') do %%j-%%i-%%k-%%l-%%m /log:%temp%\officeupdates.log /passive /norestart

The following Visual Basic script provides functionality similar to the preceding batch file. This script installs all Microsoft Self-Extractor files that are contained in the folder in which you place the script. The code specifies that the Microsoft Self-Extractor packages be installed silently, and enables logging so that the log files are generated in the Windows temporary folder. These switches are not intended for executable (.exe) files other than Microsoft Self-Extractor files. Therefore, we recommend that you do not include other kinds of .exe files in the folder that contains the Self-Extractor files.

Dim wShell 'As WshShell

Dim fso 'As FileSystemObject

Dim f 'As File

Dim sLogName 'As String

Dim sPatchFolder 'As String

Dim sPatchCmd 'As String

Const kTempFolder = 2

On Error Resume Next

sPatchFolder = Replace(Wscript.ScriptFullName, Wscript.ScriptName, "")

Set fso = CreateObject("Scripting.FileSystemObject")

Set wShell = CreateObject("WScript.Shell")

For Each f In fso.GetFolder(sPatchFolder).Files

If UCase(Right(f.Name, 4)) = ".EXE" Then

sLogName = fso.GetSpecialFolder(kTempFolder) & "\" & Left(f.Name, Len(f.Name) - 3) & "log"

sPatchCmd = f.Path & " /quiet /norestart /log:" & sLogName

wShell.Run sPatchCmd, 0, True

End If

Next

If you are deploying software updates after an initial installation of the 2007 Office system by using Microsoft Self-Extractor files, you can use a text editor, such as Notepad, to modify the Visual Basic script and batch file samples in this section to suit your specific requirements. Save the files after you complete customizations. You can then run the script or batch file to chain the installation of the new Microsoft Self-Extractor packages. In this case, the basic process would be as described in the following procedure, which uses SP2 for the 2007 Office system as an example. The information applies to other Office updates as well.

Deploy all the Microsoft Self-Extractor packages contained in a folder

For information about how to use the Updates folder to incorporate the installation of updates with an initial installation of the 2007 Office system products, see Deploying software updates with the initial 2007 Office system installation.

1. Copy the compressed 2007 Office system CD image to a network location. For information, see Create a network installation point for the 2007 Office system.

2. Use the Office Customization Tool to make any necessary modifications to the installation. Save that customization patch (.msp file) to the Updates folder. As noted previously, ensure that the file name begins with "1." For information about customizations, see Office Customization Tool in the 2007 Office system and Customize the 2007 Office system.

3. To modify the Config.xml file, use the Config.xml file that is located in the root of the product folder for the product that you are installing. Use a text editor such as Notepad to modify the file. For example, you can specify installation options (such as the path of the network installation point, the product to install, and custom setup options) and specify the languages to install. For information, see Config.xml file in the 2007 Office system.

   When you complete the Config.xml customizations, save the Config.xml file. You can use the /config Setup command-line option to specify the location of the Config.xml file, as shown in the following example:

   \\ server \ share \setup.exe /config \\ server \ share \Enterprise.WW\config.xml

4. Download the 2007 Microsoft Office Suite Service Pack 2 (SP2) (http://go.microsoft.com/fwlink/?LinkId=144524).

5. To extract the .msp patches from the Microsoft Self-Extractor file (office2007sp2-kb953195-fullfile-en-us.exe in this example), run the .exe file with the /Extract:[extract folder path] switch. For example, type the following at the command prompt:

   office2007sp2-kb953195-fullfile-en-us.exe /extract:" c:\ExtractFiles "

   This command-line starts Setup to extract the .msp files. Prior to beginning the extraction process, the Microsoft Software License Terms is displayed. After the license terms is accepted, the files are extracted. The quotation marks do not need to be used with the path, but it does make it easier to read the command line. Using quotation marks also helps avoid problems with long file name paths that contain spaces.

6. Copy the Windows Installer patch (.msp) files to the Updates folder.

7. Repeat the process for any other 2007 Office system SP2 update packages or other updates that you want to install. The Windows Installer patch file names are unique. Therefore, there should be no risk of a file being accidentally overwritten, which might cause a problem with the installation. If the product is being deployed with additional language packs, the language pack service packs would be added to the Updates folder.

   After you complete the previous steps, you can deploy the product.

1. Install all 2007 Office system applications on the test computer that will be installed on users' computers.

2. Run Microsoft Update to apply all needed 2007 Office system updates on the test computer.

3. Verify that your applications are running as expected.

4. Save the following Visual Basic script as "CollectUpdates.vbs," and then run it to extract the update files installed on the test computer to a target folder. (The script uses %Temp%\Updates as the target folder, where %Temp% is the Windows temporary folder.)

   Dim oMsi,oFso,oWShell

   Dim Patches,SumInfo

   Dim patch,record,msp

   Dim qView

   Dim sTargetFolder,sMessage

   Const OFFICEID = "000-0000000FF1CE}"

   Const PRODUCTCODE_EMPTY = ""

   Const MACHINESID = ""

   Const MSIINSTALLCONTEXT_MACHINE = 4

   Const MSIPATCHSTATE_APPLIED = 1

   Const MSIOPENDATABASEMODE_PATCHFILE = 32

   Const PID_SUBJECT = 3 'Displayname

   Const PID_TEMPLATES = 7 'PatchTargets

   Set oMsi = CreateObject("WindowsInstaller.Installer")

   Set oFso = CreateObject("Scripting.FileSystemObject")

   Set oWShell = CreateObject("Wscript.Shell")

   'Create the target folder

   sTargetFolder = oWShell.ExpandEnvironmentStrings("%TEMP%")&"\Updates"

   If Not oFso.FolderExists(sTargetFolder) Then oFso.CreateFolder sTargetFolder

   sMessage = "Patches are being copied to the %Temp%\Updates folder." & vbCrLf & "A Windows Explorer window will open after the script has run."

   oWShell.Popup sMessage,20,"Office Patch Collector"

   'Get all applied patches

   Set Patches = oMsi.PatchesEx(PRODUCTCODE_EMPTY,MACHINESID,MSIINSTALLCONTEXT_MACHINE,MSIPATCHSTATE_APPLIED)

   On Error Resume Next

   'Enum the patches

   For Each patch in Patches

      If Not Err = 0 Then Err.Clear

       'Connect to the patch file

       Set msp = oMsi.OpenDatabase(patch.PatchProperty("LocalPackage"),MSIOPENDATABASEMODE_PATCHFILE)

       Set SumInfo = msp.SummaryInformation

       If Err = 0 Then

           If InStr(SumInfo.Property(PID_TEMPLATES),OFFICEID)>0 Then

               'Get the original patch name

               Set qView = msp.OpenView("SELECT `Property`,`Value` FROM MsiPatchMetadata WHERE `Property`='StdPackageName'")

               qView.Execute : Set record = qView.Fetch()

               'Copy and rename the patch to the original file name

               oFso.CopyFile patch.PatchProperty("LocalPackage"),sTargetFolder&"\"&record.StringData(2),TRUE

           End If

       End If 'Err = 0

   Next 'patch

   oWShell.Run "explorer /e,"&chr(34)&sTargetFolder&chr(34)

5. Verify that all of the needed .msp files are in the target folder (%Temp%\Updates).

6. Copy all .msp files from %Temp%\Updates on the test computer to the Updates folder on the 2007 Office system network installation point.

1. Open the Config.xml file in a text editor tool, such as Notepad.

2. Enter the options that you want to use for the SetupUpdates element, as shown in the following example syntax:

   <SetupUpdates [CheckForSUpdates="Yes"] [SUpdateLocation= path-list ] />

   In this case, path-list lists the fully qualified paths to folders, separated by semicolons.

3. Save the Config.xml file in the same folder that contained this file before you edited it.